Corel FORUM

Martin Nez

Witam,
mam problem z pewnym skryptem... Otóż w oknie mam wrzucony PictureBox o nazwie "imgPodglad", a kod wygląda tak:

Kod:

Private Sub lbxListaPozycji_Click()
' załadowanie miniatury obrazka
Dim picObraz As StdPicture
Set picObraz = Nothing
Set picObraz = LoadPicture(sciezka & "plik.jpg")
imgPodglad.Picture = picObraz
End Sub

Problem dotyczy działania tego kodu z plikami jpg zapisanymi w CMYKu (z RGB jest wszystko ok). Otóż program wiesza się wywalając błąd "Automation error" (cokolwiek to jest).
Szukam rozwiązania, które pozwoli wciągać do tego boksa obrazy w CMYKu lub chociaż rozpozna czy obrazek jest RGB czy CMYKiem i wywali odpowiedniego MsgBoksa.

W sumie z tego co kojarzę ludzi tutaj to pewnie pytanie do MaroQ lub chezare'a, więc Wy dwoje zwróćcie proszę szczególnie uwagę czy nie spotkaliście się może z takim problemem.

Pozdr,
MN

bidon184

nie znam sie na skryptach do corela ale np we flash ten wers Set picObraz = LoadPicture(sciezka & "plik.jpg") robi duza roznice poniewaz nie zawiera informacji o pliku czyli exif moim zdanie powinno wystarczyć zamiana koncowki na jpeg

Martin Nez

bidon184,
Sprawdziłem na szybko i niestety w moim przypadku to nic nie daje...
Swoją drogą całe szczęście, bo mam folder z 12 000 zwymiarowanych zdjęć zapisanych w jpg. ;D
Ale dzięki za chęci. :) Gdyby coś jeszcze przyszło Ci do głowy daj znać.

Pozdr,
MN

bidon184

no raczej na nic wiecej nie wpadne :-)

bo jednak cmyk to rzeczywistosc a flash to wirtual,ale osobnicy ktorych wymieniles twardo stoja na ziemi wiec zapewne pomysly maja :-)

,no hym,ogolnie to z ta miniatura jest cos nie tak bo miniatury sa w rgb mimo ze podglad jest np w tiff,hym no nie wiem nie bede sie wymądrzał,są o wiele lepsi ode mnie :-)

chezare

Bardzo to miłe, że ktoś uważa mnie za fachowca od pisania makr w Corelu, ale prawda jest niestety taka, że nie mam o tym bladego pojęcia, a to że rozwiązałem dwa problemy na krzyż i to pewnie w ułomny sposób, to wynik tego, że uważam, że to nie ma nic wspólnego z czarną magią i jak ktoś chce, to może :-)

Szaman to co innego, bez problemu ustali dlaczego ta metoda nie lubi cmyka.
Ja bym mógł się temu przyjrzeć, bez żadnej gwarancji że coś wymyślę, ale póki co, to nie mam pojęcia co to jest ten picturebox i jak to się wstawia do dokumentu Corela?

Martin Nez

chezare
nie do dokumentu, a do UserForma w VBA. ;] Spróbuj, może na coś wpadniesz...
Pozdr,
MN

chezare

Dalej jestem głupi.
Mógłbyś opisać o co w tym chodzi? Jak to działa?
To ma być coś takiego jak okno do importu grafiki?

Z tego co ja widzę, to obrazek w formularzu można umieścić poprzez komponent o nazwie Image, albo jako tło formatki?
Ja mam tutaj zabytkowego Corela, może w nowszych wersjach lista komponentów jest inna,
PictureBox to to samo co Image?

Martin Nez

Dokładnie to samo. Sorry, że nie dałem od razu screena, a nawet nie myślałem, że ten komponent ma inną nazwę... Więc jak już masz taki formularz to teraz chodzi o to, że nie mogę załadować jpga w CMYKu, a działa tylko z RGB.
Pozdr,
MN

maroQ

Martin Nez

Witam,
co prawda nie odpowiedziałeś na moje pytanie, ale Twój wywód n/t VB.NET mnie zainteresował. Niestety nie wiem nawet jak zacząć, może masz jakiś prosty przykład, który mógłbym wykorzystać do analizy? Może to być nawet prosta aplikacja wywalająca formularz z jakimś Labelem lub czymś takim. Chodzi mi bardziej o technikę połączenia tego z Corelem itp. Dotychczas pracowałem tylko z plikami GMS.

Niestety nie przerobię już teraz całego makra na VB.NET, ponieważ zbyt dużo czasu poświęciłem na napisanie tego co już mam, a ten błąd z plikami cmykowymi to w sumie taki detal, który stwierdziłem, że muszę poprawić.

Co do mojego problemu - zauważyłem, że wcale nie chodzi o pokazanie obrazka w komponencie Image... Błąd wyskakuje linię wcześniej - przy ładowaniu pliku do picObraz (StdPicture). Może w związku z tym jakieś pomysły?

Pozdr,
MN

chezare

Przyjrzałem się temu komponentowi w starym vba i niestety Szaman ma rację, numer z grafiką 32 bitową nie przejdzie.
Jeśli dobrze zrozumiałem i te obrazki mają służyć tylko do jakiegoś podglądu, to można je przekonwertować do rgb, ilość nie jest przeszkodą, wiele prostych programów zrobi to automatycznie, albo zapomnieć o starym vba?
Zresztą wyświetlanie grafiki w CMYK na monitorze nie wydaje mi się rzeczą naturalną, bo do wyświetlania i tak musi to zostać zamienione na RGB?

Martin Nez

Też niestety nie trafiłem jeszcze na rozwiazanie mojego problemu...
Nie byłoby przeszkodą przekonwertowanie wszystkich 12 000 obrazków na RGB (przecież można napisać krótkie makro do Corela PP ;) ), ale chciałbym zabezpieczyć się na przyszłość. Niestety do folderu z tymi obrazami nie tylko ja wrzucam zdjęcia, a nie sposób kontrolować każdego nowego pliku, który ktoś zapisze. Dlatego chciałbym, żeby chociaż wyskakiwał MsgBox zamiast zawieszania makra.
Co do zapisywania i wyświetlania grafik w CMYKu - Ty to wiesz, ja to wiem... ;] Ale nie każdy w firmie, w której pracuję. ;)
Mimo wszystko - dziękuję za chęć pomocy.

Pozdr,
MN

chezare

Zorganizuje obsługę błędów i procedura nie będzie się wykolejała przy próbie otwarcia obrazka w nieakceptowanym formacie, np. tak;

Private Sub lbxListaPozycji_Click()
' załadowanie miniatury obrazka
Dim picObraz As StdPicture
on error resume next
Set picObraz = Nothing
Set picObraz = LoadPicture(sciezka & "plik.jpg")
imgPodglad.Picture = picObraz
End Sub

albo z komunikatem

Private Sub lbxListaPozycji_Click()
' załadowanie miniatury obrazka
Dim picObraz As StdPicture
Set picObraz = Nothing
on error goto blad
Set picObraz = LoadPicture(sciezka & "plik.jpg")
imgPodglad.Picture = picObraz
goto koniec
blad:
msgbox "Nieakceptowany format grafiki"
koniec:
End Sub

maroQ

Tu macie trochę fajniejszą funkcję z obsługą różnych błędów i obrazkiem domyślnym (na wypadek błędu coś się itak wyświetli).

Kod:

Private dirname As String

Sub OpenPicture(ByVal pname As String, Optional ByVal defaultImg As String)
On Error GoTo blad
'info: https://msdn.microsoft.com/en-us/library/aa264946%28v=vs.60%29.aspx
If defaultImg = "" Then
Image1.Picture = LoadPicture()
Else
Image1.Picture = LoadPicture(defaultImg)
End If
Image1.Picture = LoadPicture(pname, , , Color)
GoTo koniec
blad:
Select Case err.Number
Case 53
MsgBox "Nie znaleziono pliku!", vbExclamation, "Error " & err.Number
Case 481
MsgBox "Nieobsługiwany typ obrazka!" & vbNewLine & "Obsługiwane formaty: bitmapa (.bmp), ikona (.ico), kursor (.cur), run-length encoded (.rle), metafile (.wmf), enhanced metafile (.emf), GIF (.gif), JPEG (.jpg)", vbInformation, "Error " & err.Number
Case -2147467259
MsgBox "Nieobsługiwany obrazek np. CMYK! ", vbInformation, "Error " & err.Number
Case Else
MsgBox "Wystąpił błąd: " & err.Description, vbCritical, "Error " & err.Number
End Select
koniec:
End Sub

Private Sub UserForm_Initialize()
dirname = "c:\"
Call OpenPicture(dirname & "pirate.jpg")
End Sub

Private Sub CommandButton1_Click()
Call OpenPicture(dirname & "Rysunek1RGB.jpg", dirname & "pirate.jpg")
End Sub

Private Sub CommandButton2_Click()
Call OpenPicture(dirname & "Rysunek1CMYK.jpg", dirname & "pirate.jpg")
End Sub

Wymagane obiekty w formularzu:
1. Pole Image1
2. Przycisk CommandButton1 z napisem RGB
3. Przycisk CommandButton2 z napisem CMYK
Na dysku trzeba mieć pliki:
1. Rysunek1RGB.jpg
2. Rysunek1CMYK.jpg
3. pirat.jpg
Katalog podajemy w zmiennej dirname.

LoadPicture wspiera maksymalnie 256 kolorów więc o CMYKu nie ma mowy.

Martin Nez

Zadziałało... Że wcześniej nie pomyślałem, żeby to wrzucić w obsługę błędów... :) Dodałem tam ładowanie domyślnego zdjęcia na "brak podglądu" ze ścieżki ustawionej na stałe i teraz super hula...
Ostatecznie procedura wygląda tak:

Kod:

Private Sub lbxListaPozycji_Click()
' załadowanie miniatury obrazka
Dim picObraz As StdPicture
Set picObraz = Nothing
On Error GoTo blad
Set picObraz = LoadPicture(sciezka & lbxListaPozycji.Value & ".jpg")
GoTo koniec
blad:
Set picObraz = LoadPicture(Application.UserDataPath & "Martinez\cmyk.nez")
koniec:
imgPodglad.Picture = picObraz

' aktywacja przycisku
btnOk.Enabled = True
End Sub

chezare,
że tak Ci przypomnę:

Cytat:

Bardzo to miłe, że ktoś uważa mnie za fachowca od pisania makr w Corelu, ale prawda jest niestety taka, że nie mam o tym bladego pojęcia

;-)
Czasami wystarczy odejść od kompa na tydzień, żeby rozwiazać jakiś problem... W tym przypadku nie miałem tygodnia, więc poprosiłem o pomoc. :-)

[edit]
maroQ
wpadliśmy w jednym momencie na ten sam pomysł. :-) w sumie niepotrzebne mi żadne komunikaty skoro ładuje domyślny plik, ale i tak dzięki za kody błędów. Może komuś się przydadzą... A może mi na przyszłość...

Jeszcze raz dzięki i pozdr,
MN

maroQ